10 PRINT : PRINT "EXAMPLE 6.5-2 SOLUTION OF PARALLEL PIPE PROBLEMS"
20 DEFINT I, N: DEF FNQ (D1, D2, D3, DH) = D1 * DH * LOG(D2 + D3 / DH)
30 READ N, QQ, RHO, KVIS, PA, ZA, ZB, G, II
40 DATA 3, 12.,2.,  .00003,  80.,100.,80.,32.2, 15
50 PRINT : PRINT "N,QQ,RH0,KVIS="; N; QQ; RHO; KVIS
60 PRINT : PRINT "PA,ZA,ZB,6,II="; PA; ZA; ZB; G; II: PRINT
70 FOR I = 1 TO N: READ L(I), D(I), EP(I): NEXT I
80 DATA 3000.,1.,.001,2000.,.6667,.0001,4000.,1.3333,.0008
90 FOR I = 1 TO N: PRINT "I,L,D,EPS="; I; L(I); D(I); EP(I): NEXT I: PRINT
100 FOR I = 1 TO N: C = SQR(G * D(I) / L(I)): E1(I) = -.9650001 * D(I) ^ 2 * C
110 E2(I) = EP(I) / (3.7 * D(I)): E3(I) = 1.784 * KVIS / (D(I) * C): NEXT I
120 X = .02 * L(1) * QQ ^ 2 / (.7854 * D(1) ^ 5 * 2! * G): ' MAX POSS. HEAD WITH FLOW THRU PIPE 1
130 HMA = SQR(X):  HMI = 0!
140 FOR I1 = 1 TO II:  S = 0!:   HF = .5 * (HMA + HMI): ' START OF BISECTION METHOD
150 FOR I = 1 TO N:  S = S + FNQ(E1(I), E2(I), E3(I), HF): NEXT I
160 IF S - QQ > 0! THEN HMA = HF ELSE HMI = HF
170 ' PRINT "S,QQ,HF="; S; QQ; HF
180 NEXT I1: HFR = .5 * (HMA + HMI): HFF = HFR ^ 2: ' FINAL VALUE OF HEAD DROP
190 FOR I = 1 TO N: PRINT "I,HFF,Q="; I; HFF; FNQ(E1(I), E2(I), E3(I), HFR): NEXT I
200 PRINT : PRINT "PB="; : PRINT USING " ###.### "; PA + (ZA - ZB - HFF) * RHO * G / 144!